# Contributor:	Thomas Mudrunka <harvie@@email..cz>
# Maintainer: 	Thomas Mudrunka <harvie@@email..cz>
# You can also contact me on http://blog.harvie.cz/

pkgname=dnssec-tools
pkgver=1.7
pkgrel=1
pkgdesc="Set of software tools, patches, applications, wrappers, extensions, and plugins that will help ease the deployment of DNSSEC related technologies"
url="http://www.dnssec-tools.org/"
license="Custom"
arch=('i686' 'x86_64')
depends=(perl perl-timedate perl-net-dns perl-net-dns-sec)
install="${pkgname}.install"
source=("http://www.dnssec-tools.org/download/${pkgname}-${pkgver}.tar.gz")
md5sums=('f3dfe18ae50cf65594936e1684d469d0')

build() {
	cd ${srcdir}/${pkgname}-${pkgver}/ || return 1
	msg 'Configuring...'
	./configure\
		--exec_prefix=/usr --prefix=/usr\
		--sysconfdir=/etc --mandir=/usr/share/man\
		--with-resolv-conf=/etc/resolv.conf\
		--with-root-hints=none\
		--with-ipv6\
		--with-nsec3\
		--with-dlv 

	msg 'Fixing bugs...'
	grep VAL_ROOT_HINTS ./validator/libval/val_policy.h	|| {
		msg2 'fixing missing VAL_ROOT_HINTS in ./validator/libval/val_policy.h'
		root_hints="$(grep '^VAL_ROOT_HINTS=' ./validator/config.log | head -n 1 | tr = ' ' | tr "'" '"' | sed -e 's/\//\\\//g')"
		cat ./validator/libval/val_policy.h | sed -e 's/#include "val_parse.h"/#include "val_parse.h"\n#define '"$root_hints"'/' > tmp
		mv tmp ./validator/libval/val_policy.h
  }

	msg 'Building...'
	make

	msg 'Installing files to package...'
		make -j1 install DESTDIR="${pkgdir}"
	msg2 'configuration files'
		cp -r validator/etc/* "${pkgdir}/etc/${pkgname}/"
		rm -rf "${pkgdir}/etc/${pkgname}/${pkgname}.conf" #will be generated in post_install
	msg2 'license informations'
		mkdir -p "${pkgdir}/usr/share/licenses/${pkgname}/"
		cp COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
}